Useful macros for mages

Classes
Class races	Death Knight	Demon Hunter	Druid	Ev	Hunter	Mage	Monk	Paladin	Priest	Rogue	Shaman	Warlock	Warrior
Quests	Death Knight	Demon Hunter	Druid	Evuid	Hunter	Mage	Monk	Paladin	Priest	Rogue	Shaman	Warlock	Warrior
Abilities	Death Knight	Demon Hunter	Druid	Evuid	Hunter	Mage	Monk	Paladin	Priest	Rogue	Shaman	Warlock	Warrior
Trainers	Death Knight	Demon Hunter	Druid	-	Hunter	Mage	Monk	Paladin	Priest	Rogue	Shaman	Warlock	Warrior
Armor sets	Death Knight	Demon Hunter	Druid	Evuid	Hunter	Mage	Monk	Paladin	Priest	Rogue	Shaman	Warlock	Warrior
Useful macros	Death Knight	Demon Hunter	Druid	-	Hunter	Mage	Monk	Paladin	Priest	Rogue	Shaman	Warlock	Warrior
Class Halls	Death Knight	Demon Hunter	Druid	-	Hunter	Mage	Monk	Paladin	Priest	Rogue	Shaman	Warlock	Warrior

Macros
General guides
Macros Beginners Guide Making a macro Macro conditionals Macro commands Category:Macros
Useful macros by class

Macro Formatting Guidelines

Note: With the release of 6.0.2, many spells have been renamed, and much of the scripted command functionality has been modified. In an effort to keep Wowpedia posts relevant, please re-validate and re-post macros that work in the current version.

Re-Creating Old Macros

When re-creating a macro in Useful macros please

• follow the example format posted below (to get the frame around your macro, add a space before you start it)
• describe what it does
• note the version of WoW in which you tested it
• remove it from the Old Macros page

Example Macro

/y Hooray, I made a macro!

• Use: This yells, "Hooray, I made a macro!"
• Works in 6.x

General Macros

Conjure Mana Gems

#showtooltip Mana Gem
/cast [button:2] Conjure Mana Gem
/stopmacro [button:2]
/use Mana Gem

• Validated: 4.0.3
• Use: Left-clicking this macro will use a  [Mana Gem]. Right-clicking it will cast [Conjure Mana Gem].

#showtooltip [nomod] Mana Gem; [mod:shift] Conjure Mana Gem;
/cast [nomod] Mana Gem; [mod:shift] Conjure Mana Gem;

• Validated: 4.0.3
• Use: This macro uses shift instead of the mouse buttons. Using this macro will use a  [Mana Gem]. Holding alt while using this macro will cast [Conjure Mana Gem].

Polymorph

Simple Announce Polymorph

#showtooltip Polymorph
/cast Polymorph
/stopmacro [noharm]
/stopmacro [dead]
/e polymorphs %t.

• Validated: 4.0.3

Use: Casts [Polymorph] and announces it with an emote.

#showtooltip Polymorph
/castrandom [harm] Polymorph, Polymorph(Rabbit), Polymorph(Turtle)
/stopmacro [noharm]
/stopmacro [dead]
/e polymorphs %t.

• Validated: 4.0.3
• Use: Casts a random [Polymorph] spell and announces it with an emote.

Buffs

#showtooltip
/castsequence [@player] reset=4 Arcane Brilliance, Molten Armor, Dampen Magic

• Validated: 4.0.3
• Use: Refreshes your Buffs

Shield one button

#showtooltip 
/castsequence [@player] reset=4 Ice barrier, Mana shield

Cast and Remove Ice Block

#showtooltip Ice block
/stopcasting
/cast Ice block
/cancelaura [mod:shift] Ice block

• Validated: 4.0.3
• Use: Press to cast [Ice Block], hold shift and press to remove it.

Start buffs, conjure rations, and eat/drink in one click

#showtooltip Croissant
/castsequence [btn:1] reset=10 Arcane Brilliance,Molten Armor,Conjure Water, Conjure Food
/use [btn:2]Conjured Glacier Water
/use [btn:2]Conjured Croissant

This macro is good for start-up as it allows initial buffs, and the conjuring of food and water; or it will consume both food and water with a single click. If you left-click on it, or click on it with a keyboard hotkey, it goes through a sequence which will give the intellect buff, and molten armor - feel free to change that to which ever armor you prefer - followed by conjure water and food. By putting the buffs first, when they run out and you are not out of food, you can simply left click on it twice to renew your buffs. I used to have gem conjuration in the sequence as well, but since they no longer vanish and throw an error if you try to conjure one when you still have one, I thought they did not belong here anymore.

If you right click on it, you will sit, eat, and drink, in one click. By setting #showtooltip to the food - change it to which ever food you conjure - you will see a big red ? when you first log on, to remind you that you need to run it, and, once you have run it, you will see the number of foods you have in stock. At the lower levels you tend to summon 2 more waters than foods, but if you always eat and drink together, it is unlikely that you will run out of water before you run out of food, and excess waters can easily be thrown away; or they will vanish on their own when you log out.

Start buffs, conjure rations, and eat/drink in one click (Grinder Version)

#showtooltip Conjured Glacier Water
/target player
/castsequence [btn:1,mod:shift] Conjure Water,Conjure Food; [btn:1] reset=10 Dampen Magic,Arcane Brilliance,Molten Armor
/use [btn:2]Conjured Glacier Water
/use [btn:2]Conjured Croissant

Same as above but with more finite control. Left-click to cast your buffs in sequence (dampen/amply magic, intellect, armor). Shift-click to conjure your water and food. Right-click to eat/drink.

If you're like me you'll run out of water/food long before your buffs run out. Dampen/Amply Magic are placed first in the buff list to account for the 10 minute duration; left-click once to refresh just this or multiple times to refresh them all.

Cataclysm Polymorph Focus Macro

A modified version of the old Polymorph Mouseover/Focus macro.

This polymorph macro will do the following:

1. Clear your focus if your old focus target is dead
2. Clear your focus if your old focus target doesn't exist anymore
3. Set your focus on what you have targeted if you don't have a focus already OR if your current focus is friendly
4. Set your focus on your mouseover target if you have one
5. Polymorph the Focus target.

/clearfocus [target=focus,dead][target=focus,noexists]
/focus [target=mouseover,harm][target=focus,noexists]
/cast [target=focus] Polymorph

You can also use this macro without the mouseover feature; just delete the word mouseover (and the comma immediately after it) from the macro and you're set.

This macro will also work for other crowd control spells like Fear, Hex, etc.

• Tested in 4.0.3a

Arcane Macros

Standard Rotation

This will cast Arcane Blast 4 times to build up debuffs, then cast Arcane Barrage. When Missle Barage Procs hold shift to cast Arcane Missles after the fourth Arcane Blast

#show Arcane Blast
/cast [mod:shift, nochanneling] Arcane Missiles;
/castsequence [nochanneling] reset=10/nocombat Arcane Blast, Arcane Blast, Arcane Blast, Arcane Blast, Arcane Barrage

High Damage Blizzard

#show Blizzard
/cast Icy Veins
/cast Blizzard

Instant Flamestrike

#show Flamestrike
/cast Presence of Mind
/cast Flamestrike

Decurse

This is particularly good if you keybind your mousewheel to it.

#show Remove Curse
/cast [target=mouseover,noflying,nomounted,nodead,help] 
Remove Curse; [target=mouseover,noflying,nomounted,nodead,harm] Counterspell; [flying,combat] Slow Fall

Fire Macros

Living Bomb, Fireball

/castsequence reset=12/target/combat Living Bomb, Fireball, Fireball, Fireball, Fireball

Frost Macros

Frostbolt and Pet Attack

You can replace frostbolt with any other spell you use alot and it makes the water elemental attack faster.

#showtooltip Frostbolt
/cast Frostbolt
/petattack

AoE Grinding

May not the be choice for higher levels, but for AoE leveling grinding as frost its good.

#showtooltip
/castsequence reset=10 Frost Nova, Ice Barrier, Icy Veins, Blizzard, Blink, Cone of Cold

Conjuring, Food and drink

Eating and drinking

there are some general macros for food an water management on the Useful macros site

All In 1 Food Macro

#showtooltip
/cast [btn:2][mod:shift] Conjure Refreshment
/cast [btn:3][mod:ctrl] Ritual of Refreshment
/stopmacro [mod]
/use [btn:1] Conjured Mana Strudel

• Use: This macro is used for one button using/conjuring refreshments.
  • Default: Lets you eat conjured refreshments
  • Modifiers; Shift casts Conjure Refreshment; Ctrl it casts Ritual of Refreshment.
  • Buttons: btn1 is default, btn2 is simillar to the shift modifier, btn3 is similar to the ctrl modifier.
• Works in 3.3.5

All in 1 Food Macro (Food + Water)

#showtooltip
/cast [btn:2,nomod][mod:shift] Conjure Water; [btn:2,mod][mod:alt] Conjure Food; [btn:3][mod:ctrl] Ritual of Refreshment
/stopmacro [mod]
/use [btn:1] Conjured Glacier Water
/use [btn:1] Conjured Croissant
/use [btn:1] Conjured Mana Pie

• Use: This macro is used for one button using/conjuring food & water.
  • Default: Lets you eat conjured food/water/refreshments
  • Modifiers; Shift casts Conjure Water; Ctrl it casts Conjure Food; Ctrl it casts Ritual of Refreshment.
  • Buttons: btn1 is default; btn2+nomod is simillar to the shift modifier; btn2+mod is simillar to the alt modifier; btn3 is similar to the ctrl modifier.
• Works in 3.3.5

OLD MACROS BELOW

The macros below this line have not been validated to work in 3.1. Use at your own risk.

Combat

Living Bomb

For those who have their UI set up to see their focus target and the target's debuffs, this helps you see when living bomb will go off so you can plan a recast.

#showtooltip Living Bomb
/focus
/cast Living Bomb

Anti-chain-fear

For those of you Blood Elves like me out there that can only counter chain fear three times, allowing the fourth one to hit you and the next lock to have full fear power over your toon, This is to help.

/cancelaura Ice Block
/cast [modifier:shift]Counterspell
/cast Ice Block

Left-click to ice block, or shift-click to drop block if you're in it, cast CS, and if ice block is off CD, block. Thus, you can click it out of the first fear then shift click to get right back into it the second they start casting fear again.

this gives you 8 seconds of time before they can fear again... and if specced right, 4 before they can do anything else, either.

Spam-able Frostbolt w/ pet attack

disables the annoying error sound and clears ui errors from the screen while also telling any existing water elemental to attack your current target. Also switches to the next target when your target dies (less downtime)

#showtooltip Frostbolt
/targetenemy [combat, noexists]
/console Sound_EnableSFX 0
/Cast Frostbolt
/console Sound_EnableSFX 1
/run UIErrorsFrame:Clear()
/stopmacro [target=pettarget,exists]
/petattack

Frost Nova / Cold Snap

This will cast frost nova on first press. If frost nova is still in cool down it will cast cold snap on second press, and it will cast frost nova on third press. The stop casting is in case you want to use it to interrupt another spell(ie they run in close while casting frost bolt).

/stopcasting
/castsequence reset=21 Frost Nova, Cold Snap

Quick Counterspell

Casts Counterspell immediately, cancelling any spellcast in progress. This helps ensure that you will stop your opponent's cast in time.

#showtooltip Counterspell
/stopcasting
/cast Counterspell

Silence

Casts much like the above except I added Arcane Torrent if counterspell is on cooldown, just in case you need to interrupt another spell cast (for all you BE mages out there like me). If you select the "?" icon then it will show the image of which spell you're going to use.

#showtooltip
/stopcasting
/castsequence reset=24 Counterspell, Arcane Torrent

I tried to play around with it so that if you felt the need you could shift click it to use arcane torrent (silence more than 1 enemy) but I couldn't figure out how to do it, if someone wants to add in to the macro to allow this, please go ahead.

#showtooltip
/stopcasting
/castsequence [button:2][modifier:shift] Arcane Torrent; reset=24 Counterspell, Arcane Torrent

This will let you cast - with shift and any button or button 2, Arcane Torrent, otherwise the normal sequence of counterspell followed by Arcane Torrent

Quick Ice Barrier

Similar to Quick Counterspell, casts Ice Barrier immediately, cancelling any spellcast in progress, allowing you to absorb damage now instead of later.

#showtooltip Ice Barrier
/stopcasting
/cast Ice Barrier

Trinket, then Cast

Pops two trinkets (whatever is in the 13th and 14th inventory slots) and finishes with a damage spell. This boosts DPS by reducing the number of keystrokes or clicks necessary for this common cast sequence.

 #showtooltip Frostbolt
 /use 13
 /use 14
 /cast Frostbolt

Each action has the potential to fail (when the trinkets are on cooldown or you lose line of sight on your opponent) and produce an error message and sound. Suppressing these errors makes the macro more pleasant to spam. Add this line for error suppression:

 /script UIErrorsFrame:Clear()

To disable the annoying error sound you get when your trinkets are on cooldown you can add the use the following:

 #showtooltip Frostbolt
 /run SetCVar("Sound_EnableSFX","0")
 /use 13
 /use 14
 /run SetCVar("Sound_EnableSFX","1")
 /cast Frostbolt

The I Win Button

aka PoM Pyro, the largest burst of damage a mage can deliver. Requires an arcane/fire spec. Cast the following sequence instantly and with a single button press:

• Presence of Mind, to make Pyroblast an instant cast
• Arcane Power, increasing spell damage and mana consumption by 10% (Reduced from 30%) for the next 15 seconds.
• Pop first trinket (probably something that boosts damage or crit)
• Pop second trinket (same deal)
• Pyroblast

No longer needs /stopcasting after the PoM and AP to get all this to happen with a single button press.

#showtooltip Pyroblast
/cast Presence of Mind
/cast Arcane Power
/use 13
/use 14
/cast Pyroblast

Anti Grounding Totem Ice Lance

• When used, this macro will cast Ice Lance on the nearest Grounding Totem without you losing your current target.
• If no Grounding Totem exists it will simply cast Ice Lance on your current target. NOTE: while a slight edit will make this a good macro for removing other totems, this macro is absolutely unnecessary for removing grounding totems because grounding totems force harmful spells to target them...that's their purpose.

#showtooltip Ice Lance
/stopcasting
/target [exists] Grounding Totem
/cast Ice Lance
/targetlasttarget

NOTE: Grounding Totem Makes the exact same effect.

Cast on mouseover or target

This macro will attempt to cast Counterspell on your mouseover target. If your mouse is not targeting someone, it will cast Counterspell on your current target instead. Does nothing if the target is friendly.

It is also excellent for use with Ice Lance, as well as non-Mage abilities including Earth Shock, Blind, Warlock curses, Feral Charge etc.

#showtooltip Counterspell
/stopcasting
/cast [@mouseover, harm, nodead][harm, nodead] Counterspell
/run UIErrorFrame:Clear();

Polymorph

Announce Sheep

"Dude! Quit breaking my sheep!" You've said it before, and you'll say it again. Might as well make it a macro. And since you're already writing a macro, might as well make the announcement *before* they can break your sheep.

This macro will first cast Polymorph, then (if your target was sheepable) announce (in party chat) the name of the mob you're sheeping. If you have no target, if your target is dead or if your target is friendly, you will not successfully sheep nor will you announce the attempt.

/cast Polymorph
/stopmacro [noexists] [dead] [help]
/p Sheeping %t. Back off it.

Sheep Focus

Using focus to keep an eye on your sheep can make you more reliable cc while also maximizing your DPS during the sheep's lifespan. The following macro gives you a single button that automatically manages your sheep as a focus until it dies or until you manually replace it with your current target.

When you click, if you're not already watching a sheep, your current target is put in focus and Polymorphed. Any subsequent clicks will resheep your focus, leaving you free to target something else for damage. Once your sheep is killed, click again to set your current target as focus and sheep it.

If you need to sheep a different target before your current sheep is down, target the new sheep, hold shift and click to make the change.

#showtooltip [target=focus,harm] [] Polymorph
/stopcasting
/clearfocus [modifier:shift][target=focus,dead][target=focus,noexists]  
/focus [target=focus,noexists]  
/cast [target=focus] Polymorph

Note that using this macro will interrupt any cast in progress and immediately focus and Polymorph.

Full Polymorph/Focus Macro

This polymorph macro will do the following:

1. Clear your focus if your old focus target is dead
2. Clear your focus if your old focus target doesn't exist anymore
3. Set your focus on what you have targeted if you don't have a focus already
4. Place a Star marker over the head of the focus target (if you are group/raid leader/assistant)
5. Polymorph the Focus target
6. Announce the sheeping.

This allows one button to do the whole sheeping process without the need for a separate /clearfocus button (though an additional macro that does a /script SetRaidTarget("focus",0) and then a /clearfocus would be useful to let the group know the sheep is free game now might be useful)

#showtooltip
/clearfocus [target=focus,dead]
/focus [target=focus,noexists]
/script SetRaidTarget("focus", 1)
/cast [target=focus]Polymorph
/stopmacro [nogroup]
/s --== Sheeping and Marking "%t" ==--

As of 2.1, you can also use %f to insert your focus name in chat just like %t inserts your target. Thus, to alert your party that you are sheeping (or re-sheeping) your focus and not your target, try this instead of the last line above:

/s --== Sheeping and Marking "%f" ==--

Target Tracking

This polymorph macro will do the following:

1. Left-Click: Set saved target to current target and sheep it
2. Right-Click: sheep saved target (do not change current focus)
3. Shift-Left-Click: set focus to saved target

/focus [button:1]
/cast [button:1,nomodifier:shift] Polymorph; [target=focus,exists,button:2,nomodifier:shift] Polymorph
/stopmacro [nomodifier:shift]
/target focus

Target Tracking with Instant Crowd Control Option

This polymorph macro will do the following:

1. Left-Click: Set saved target to current target and sheep it
2. Right-Click: sheep saved target (do not change current focus)
3. Shift-Left-Click (first click): set saved target to focus, cast Presence of Mind
4. Shift-Left-Click (second click): set saved target to focus, sheep it
5. Shift-Right-Click (first click): set focus to saved target, cast Presence of Mind
6. Shift-Right-Click (second click): set focus to saved target, sheep it

/focus [button:1]
/cast [button:1,nomodifier:shift] Polymorph; [target=focus,exists,button:2,nomodifier:shift] Polymorph
/stopmacro [nomodifier:shift]
/target [button:2] focus
/castsequence Presence of Mind, Polymorph

Polymorph with Focus, favouring Mouseover

This is a modified version of the focus-following macros above, that will reset your focus to your mouseover target. This means you can switch polymorph focus without changing your current target.

/clearfocus [target=focus,dead][target=focus,noexists]
/focus [target=mouseover,exists][target=focus,noexists]
/script SetRaidTarget("focus", 1)
/cast [target=focus] Polymorph
/stopmacro [nogroup]
/p --== Sheeping and Marking "%f" ==--

Random

1. If the target can be polymorphed, one of the listed spells will be chosen.
2. If the target can not be polymorphed, stop macro processing.
3. Otherwise, send an emote stating polymorph is in progress.
4. Since 2.3 Polymorph Turle and Pig have been changed from Polymorph: Pig to Polymorph(Rank 1:Pig)
5. In patch 3.0.2 and beyond The spells are named Polymorph(Rank 4), Polymorph(Pig), and Polymorph(Turtle)

/castrandom [harm] Polymorph, Polymorph(Pig), Polymorph(Turtle)
/stopmacro [noharm]
/emote randomly polymorphs %t.

Conjuring, Food and drink

Conjure/Consume Food, Water, and Gem all in one button

Left click to conjure, right click to consume. Click normally to conjure/drink water, shift-click to conjure/eat food, and control-click to conjure/consume mana gem (replace names of items with whatever the name of what you are currently conjuring is) If you use the ? Icon with this macro, the icon will automatically change based on what buttons you are holding.

/cast [button:1,nomodifier]Conjure Water;[button:1,modifier:shift]Conjure Food;[button:1,modifier:ctrl]Conjure Mana Jade;
/use [button:2,nomodifier]Conjured Spring Water;[button:2,modifier:shift]Conjured Pumpernickel;[button:2,modifier:ctrl]Mana Jade;

Another conjure/consume food/water/gem in one button

A right click will cycle through conjuring food, water, and a mana gem, resetting the cycle after 8 seconds. A right click with shift held will conjure a mana gem, regardless of castsequence position. Left clicking will drink with no modifiers, eat with control, and use the mana gem with shift. Note that this is MUCH more useful with the question mark icon.

/cast [modifier:alt]Conjure Mana Agate
/castsequence [nomodifier,button:2] reset=8 Conjure Water,Conjure Food,Conjure Mana Agate
/stopmacro [button:2]
/use [nomodifier]Conjured Purified Water;[modifier:ctrl]Conjured Rye;[modifier:shift]Mana Agate

Other utility

Teleporting to Stormwind or Ironforge

This macro is designed to teleport you to Stormwind or Ironforge, and also displays how many runes you have left. Right click = Ironforge Ctrl+Right Click = Stormwind. Enjoy!

#show Rune of Teleportation
/say Teleporting, Cya!
/cast [button:2,nomodifier] Teleport: Ironforge
/cast [button:2,modifier:ctrl] Teleport: Stormwind

All Teleports + Portals on 3 Buttons

These macros will take 3 slots only, and will include every available portals and teleports. modifier + left click, will teleport and modifier + right click will create a portal.(except stonard, one macro includes stonard teleport ONLY, and other one includes stonard portal ONLY)

This macro will be Silvermoon City teleport/portal if no modifier key used, will change to Thunder Bluff if "alt" key is pressed, and will change to Stonard if "shift" key is pressed. Remember; Left click teleports, right click creates portal (except stonard)

#showtooltip
/cast [nomodifier,btn:1]Teleport: Silvermoon
/cast [nomodifier,btn:2]Portal: Silvermoon
/cast [modifier:alt,btn:1]Teleport: Thunder Bluff
/cast [modifier:alt,btn:2]Portal: Thunder Bluff
/cast [modifier:shift,btn:1]Teleport: Stonard

This macro will be Orgrimmar teleport/portal if no modifier key used, will change to Undercity if "alt" key is pressed, and will change to Stonard if "shift" key is pressed. Remember; Left click teleports, right click creates portal (except stonard)

#showtooltip
/cast [nomodifier,btn:1]Teleport: Orgrimmar
/cast [nomodifier,btn:2]Portal: Orgrimmar
/cast [modifier:alt,btn:1]Teleport: Undercity
/cast [modifier:alt,btn:2]Portal: Undercity
/cast [modifier:shift,btn:1]Portal: Stonard

This macro will be Shattrat City teleport/portal if no modifier key used, will change to Dalaran if "alt" key is pressed, and will change to Stonard if "shift" key is pressed. Remember; Left click teleports, right click creates portal.

#showtooltip
/cast [nomodifier,btn:1]Teleport: Shattrat
/cast [nomodifier,btn:2]Portal: Shattrat
/cast [modifier:alt,btn:1]Teleport: Dalaran
/cast [modifier:alt,btn:2]Portal: Dalaran

Mount and keep going

This macro is designed to let you keep running through stuff you don't want to fight without taking damage (and thus not being Dazed). It will always mount you, but if you are targeting something dangerous, it will put up [Mana Shield] first.

#show Chestnut Mare Bridle (or whatever your mount item is)
/cast [nomounted,harm] Mana Shield
/stopcasting
/use Chestnut Mare Bridle (or whatever your mount item is)

Buffing

 #Showtooltip Arcane Brilliance
 /cast [target=player,button:1] Arcane Brilliance
 /cast [button:2] Arcane Brilliance

Use: By clicking the left mousebutton you buff yourself, by clicking the right mousebutton you buff your current target (the default way). You can also change the spell ('Arcane Brilliance' used in the example) to whatever you like (i.e. 'Remove Curse').

Better Slow Fall

Removes the need to target yourself if you are not targeting someone else that is friendly. I.E. Make sure that you aren't targeting any friendlies when you are falling so it will cast it on yourself

/cast [help] [@player] Slow Fall

All 3 armors on one button

Left click for Molten Armor, right click for Frost Armor, and alt-click for Mage Armor. Very handy for conserving hotbar space and the like. You can edit the first line to have it display whichever armor's tooltip you prefer, simply change the name of the spell.

#showtooltip Molten Armor;
/cast [button:2] Frost Armor; [nomodifier:alt] Molten Armor; Mage Armor;

This macro is similar, but buffs Molten Armor with left click, Ice Armor with right click, and Mage Armor with middle mouse click (scroll wheel button).

/cast [button:2] Ice Armor; [button:3] Mage Armor; Molten Armor;

This is an alternative version that just uses modifier keys instead of different mouse buttons. Also removing the spell name from the showtooltip allows it to show the armor that will be cast before pressing the button.

#showtooltip
/cast [nomod] Frost Armor; [mod:ctrl] Molten Armor;  [mod:shift] Mage Armor;

Grouping and raiding

Easy Remove Curse Macro

This macro makes it so you can easily remove curses from party members by continually clicking the macro button. The first click will target you, the second will target the closest party member to you. This continues to all party members within range.

For party:

/targetparty
/cast Remove Curse

For raid:

/targetraid
/cast Remove Curse

Hover-Target Decurse

This macro comes from the Discord Mods forum and is extremely useful for raiding, allowing you to decurse a member of your party/raid without having target them. Just hover your mouse over the person's frame in the raid window and hit the key that binds this macro. When using a raid window tuned to show who is in need of decursing (CT Raid comes to mind) this is makes for extremely fast decursing without having to change targets.

/cast [target=mouseover,exists] Remove Curse

Elemental / Pet

Some of these ideas are taken from Pet management macros for Warlocks. Having to manually control your 45s pet (or even 1 minute with talents) as a mage is counter productive, he's only around for 45s you should try and maximise his efforts as much as possible.

Frostbolt+Attack

This instructs your pet to stay where he is and start casting his Frostbolt while you cast your Frostbolt. You could also cater this macro to any other spells you like.

#showtooltip Frostbolt
/petstay
/petattack
/cast Frostbolt

Petfollow+Frostnova

In my experience when I'm frost nova'ing an area I tend to want to run away from things attacking me there and since a retadin can 3-shot a water elemental it's a good idea to get him out of there too. This combines frost nova w/ petfollow to give you a way to make your elemental to follow you.

#showtooltip Frost Nova
/petfollow
/stopcasting
/cast Frost Nova

Frost Nova and Pet Frost Nova

Very simple macro that makes you cast Pet Frost Nova if normal Frost Nova is on cooldown and hides error messages, incase one of those in on cooldown.

/cast Frost Nova
/click [pet] PetActionButton5
/script UIErrorsFrame:Clear()

Combining Petfollow+Frostnova+Freeze

#showtooltip Frost Nova
/petfollow
/stopcasting
 /cast Frost Nova
/click [pet] PetActionButton5
/script UIErrorsFrame:Clear()

Aggressive+Ice Block

Another good idea is to just let your pet unload on whoever when you iceblock, if you do this though, you may want make a macro or add a /petdefensive in another spell of yours to switch him back.

#showtooltip Ice Block
/petaggressive
/cast Ice Block

Summon + Freeze + Attack + Follow + Stay

This macro summons your elemental and on next press, allows you to cast freeze. If you have a hostile target, your elemental will start attacking it. To use the elemental's second freeze, simply wait for the cooldown to elapse and press the same button again. If you want your elemental to attack a different target but don't want to cast freeze yet, simply right click the screen when the aoe circle appears and you can recast it when you are ready (it doesn't affect your current spell). This is very handy if you want to spam a button to summon, attack and nova something quickly. Alt and shift will set pet to follow or stay.

/castsequence reset=60 summon water elemental, freeze, freeze
/petattack [nomodifier]
/petfollow [modifier:alt]
/petstay [modifier:ctrl]

Shatter Combo

On the first press of this macro, one of your available trinkets will be popped, Icy Veins will be cast and your Water Elemental will be summoned. The second press of this macro will bring up your pets targeting reticle for its Freeze ability and your pet will begin to attack your current target. In addition, this macro will hide any resulting error messages and temporarily disable any error sounds from playing. The key is on the second press of this macro. The idea is to simultaneously or as quickly as you can click near your target to cast Freeze and cast your own Frostbolt at the same time immediately followed by an Ice Lance. The end result is a shatter combo where your target will be frozen and hit by both your pets Waterbolt, your own Frostbolt and Ice Lance relatively at the same time, all of which will land a critical strike.

/script UIErrorsFrame:Hide();
/console Sound_EnableSFX 0
/use 13
/use 14
/cast Icy Veins
/cast [nopet] Summon Water Elemental
/cast [pet] Freeze
/petattack [target]
/console Sound_EnableSFX 1
/script UIErrorsFrame:Clear();
/script UIErrorsFrame:Show();