Wikia

WoWWiki

Useful macros for hunters

Talk56
101,547pages on
this wiki

Redirected from Useful Macros for Hunters

Classese IconSmall Deathknight IconSmall Druid IconSmall Hunter IconSmall Mage IconSmall Monk IconSmall Paladin IconSmall Priest IconSmall Rogue IconSmall Shaman IconSmall Warlock IconSmall Warrior
Class races Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Quests Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Abilities Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Spec Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Talents Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Trainers Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Glyphs Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Builds Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Tactics Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Armor sets Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Starting a Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
PvE Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
PvP Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr
Macros Dk Dr Hu Ma Mo Pa Pr Ro Sh Wl Wr


Formatting Macros Edit

Note: Commands for some of the older macros have been modified significantly. Where possible, please validate and mark with last working patch or version number.

When editing a macro on the Wiki please:

  • name it, describe what it does, and use a 'space' before each command for the 'code box'
  • note the version of WoW that you tested it in
  • if moving from another page, remove it from the old page
  • follow this Macro formatting example:
==== Macro Name ====
 /y Hooray, I made a macro!
* Use: This yells, "Hooray, I made a macro!"
* Works in 5.4.2
which creates:

Macro Name Edit

/y Hooray, I made a macro!
  • Use: This yells, "Hooray, I made a macro!"
  • Works in 5.4.2
Macrose

Useful macros
Macro commands

General guides

Beginner's guide
FAQs
Making a macro
Wiki Formatting
Category:Macros
UI Customization

Class Macros

IconSmall Deathknight IconSmall Druid IconSmall Hunter IconSmall Mage IconSmall Monk IconSmall Paladin
IconSmall Priest IconSmall Rogue IconSmall Shaman IconSmall Warlock IconSmall Warrior

Pet Edit

Uber Pet Macro Edit

This macro got its name because it gives almost complete control over your pet in a single button while also taking advantage of the focus targeting system. In order to use it you must have the spells Call Pet & Revive Pet, or simply, a Hunter's Pet. You will need to edit the macro to specify which Call Pet to use. By default it uses Call Pet 1

How the Macro works... If your pet is dead: You will cast Revive Pet. If your pet is not summoned: You will cast Call Pet 1. If your pet is not summoned but is dead you can hold shift to cast Revive Pet. If you do not have a focus: You will focus on your target and your pet will be sent to attack it. If you have a focus: You will clear focus and your pet will be recalled to follow you.

In less technical terms... If your pet is missing, dead, or you are holding down shift: Your pet will be summoned or revived. If your pet is not attacking: Your pet will attack your target. If your pet is attacking: Your pet will stop attacking and return to your side. Hunter's Mark will be cast on the target

/cast [@pet,dead][mod:shift] Revive Pet
/cast [nopet,nomod] Call Pet 1
/clearfocus [@focus,dead]
/focus [@focus,exists]player;target
/clearfocus [@focus,noharm]
/petattack [@focus,exists]
/petfollow [@focus,noexists]
/cast Hunter's Mark

One Button Call/Dismiss PetEdit

If you have a pet, shift-click will dismiss it. If not...

If you right click with no modifier, summon pet in stable slot 2. If you hold shift, call pet in stable slot 3. If you hold ctrl, call pet in stable slot 4. If you hold alt, call pet in stable slot 5. Otherwise, call pet in stable slot 1.

/cast [pet,mod:shift] Dismiss Pet
/cast [nopet,button:2]Call Pet 2; [nopet,mod:shift]Call Pet 3; [nopet,mod:ctrl]Call Pet 4;
  [nopet,mod:alt]Call Pet 5; [nopet]Call Pet 1

Revive Pet -> Call Pet (-> Mend Pet) Edit

This will revive your pet if it's dead, call your pet if you don't have him out, or mend your pet.

/cast [mod]Revive Pet; [@pet,dead]Revive Pet; [nopet]Call Pet 1; Mend Pet

If your dead pet is out of range (i.e. cannot be found by the target command), you can hold down any modifier to force Revive Pet.

Alternatively, the following macro does the same as above but without Mend Pet.

/cast [nopet]Call Pet 1; [mod][]Revive Pet


Full One button Pet Treatment Edit

This macro will revive your pet if it's dead or you hold down shift, call it if it's dismissed, mend it if it's alive, feed it if you press alt at the same time and dismiss it if you right click the button.

#show [modifier:alt] Mutton Chop
/cast [nopet] Call Pet
/cast [@pet,dead][mod:shift] Revive Pet
/cast [pet,nomod,button:1] Mend Pet
/cast [pet,nomod,button:2] Dismiss Pet
/cast [pet,mod:alt] Feed Pet
/use [pet,mod:alt] <food item>

An alternative to this is below. Left clicking while holding SHIFT or ALT will cast Revive Pet, or left clicking without holding anything will cast Mend Pet if the pet is out and at your side. If you right click, you will cast Call Pet if he's alive but not out, Feed Pet if he's by your side, and if you hold SHIFT or ALT, it will cast Dismiss Pet. Be sure to change the type of food at the bottom of the macro to the name of the food you feed your pet.

/cast [button:1,modifier] Revive Pet
/cast [button:1,@pet,exists] Mend Pet
/cast [button:2,@pet,noexists] Call Pet
/cast [button:2,pet,nocombat] Feed Pet
/cast [button:2,modifier] Dismiss Pet
/use [button:2,pet,nocombat] <food item>

No Combat Feed / Combat Mend Edit

This macro will cast Mend Pet when in combat and Feed Pet when out of combat.

Feed by food name.

/cast [nocombat] Feed Pet; [combat] Mend Pet
/use [nocombat] <food item>

-OR-

Feed by bag slot: bag #1 slot #13.

/cast [combat] Mend Pet; [nocombat] Feed Pet
/use [nocombat] 1 13

-OR-

Feed a certain food item depending on the type of pet.

/cast [pet, nocombat] Feed Pet
/use [pet:Cat/Ravager, nocombat] <food item>; [pet:Wind Serpent, nocombat] <food item>

-OR-

Hold down alt to cast Mend Pet out of combat, and shows the amount of food you have in your bags.

#show <food item>
/cast [modifier:alt][combat] Mend Pet; [pet, nocombat] Feed Pet
/use [pet, nocombat, nomodifier:alt] <food item>


Pet Attack / Follow toggle Edit

Get your pet out of that boss' AOE faster by putting Pet Attack and Pet Follow on the same button. Here's a way to toggle them by holding any modifier key:

/petattack [pet,nomodifier]
/petfollow [pet,modifier]

Or here's a way to make the toggle automatic -- if your pet is attacking, it'll call him back; otherwise he'll go to attack your target.

/petfollow [@pettarget,exists]
/petattack [@pettarget,noexists]

A downside to the latter is that you may have to retrain your fingers a bit if you're accustomed to using your Pet Attack key to make your pet switch targets.

Quick Mark & Pull Edit

This macro will mark your target, start Auto Shot and send in your pet, all at once.

#showtooltip
/cast Hunter's Mark
/cast Auto Shot
/petattack

General Edit

Hunter's Mark - Pet Attack - Pet Recall (All-In-One) Edit

This macro pretty much does everything you need it to do when it comes to starting or quickly stopping a fight. First off, the macro operates mainly off of mouseover targets; however, it will use your current target if you do not have a mouseover selected. Here's what it does in order:

  1. Cast's Hunter's Mark on your mouseover target, or current target if no mouseover exists.
  2. Targets your mouseover target. *This will not happen if you are holding a modifier*
  3. Sends your pet to attack your mouseover target. *This will not you are holding a modifier*
  4. If you press use any modifier (shift/control/alt + using the macro) it will mark the target and put your pet on passive then defensive. This stops your pet from attacking a target if it is already in pursuit. Very useful if you send your pet to the wrong target and don't want it to pull aggro.
#showtooltip Hunter's Mark
/petpassive [mod]
/petdefensive [mod]
/cast [@mouseover,harm] Hunter's Mark; [harm] Hunter's Mark
/stopmacro [mod]
/target [@mouseover,harm]
/petattack [@target,harm]

For an added auto attack add "/startattack" at the bottom of the macro to fire off an autoshot if you are in range of the target, otherwise the macro will behave the same.


Hunter's Mark - Pet Attack, Pet Follow, Call Pet/Revive Pet Edit

Hunter's Mark Macro (with Petattack, Petfollow, Call Pet/Revive Pet)
#showtooltip Hunter's Mark
/castsequence [nopet] reset=3 Call Pet 1, Revive Pet
/cast Hunter's Mark
/petattack [@target,exists]
/petfollow [@target,noexists]
/petautocastoff Growl
  • First casts Call Pet (1 in this case, choose your own).
  • If Call Pet could not be cast because pet is dead, simply hit macro again to Revive Pet.
  • Casts Hunter's Mark and /petattack at target (if exists)
  • /petfollow (if no targets exist)
  • Turns off Growl auto-cast (replace /petautocastoff with /petautocaston to turn Growl auto-cast on)


Misdirection Edit

At the start of an instance or raid, set your focus target to the Main Tank, then use this macro just before pulling to cast Misdirection on him/her without losing your target.

#showtooltip
/cast [@focus,help][help][@pet,exists] Misdirection

This will misdirect to your focus target, if that is friendly. If not, it will cast on a friendly selected target instead. If that doesn't exist either, it will misdirect on your pet. That way, the macro works as intended in any situation, without the need of pressing qualifier keys or choosing between different buttons.

Above does not seem to work, tested the below in MOP 9/28/2013.
#showtooltip
/cast [target=focus, help] Misdirection; [target=pet, exists] Misdirection; Misdirection

This will misdirect to your focus target, if that is friendly. Secondly, it will misdirect on your pet.

I haven't however tested it with help as a middle modifier.


Alternatively, you can create a macro designed to cast Misdirection on a friendly player by name. Simply replace "Tank" with the name of the player you'd like to misdirect.

#showtooltip
/cast [@"Tank"] Misdirection

Another useful macro combination for one-button misdirecting. If you select a friendly target, it will make them the focus, otherwise it will cast misdirection on whatever the focus was. If you haven't got a focus set, it will misdirect to your pet instead. Usage:

  1. Select tank and click macro button. This will set your tank as focus target. You only have to do this once, until you want to change the focus to a different player.
  2. Select the mob that you want to pull (and misdirect).
  3. Shoot away!
#showtooltip
/focus [help]
/stopmacro [help]
/cast [@focus,exists] Misdirection;[@pet,exists] Misdirection

A variation on this wonderful macro is

#showtooltip
/focus [help]
/script SendChatMessage ("You are now my FOCUS target","WHISPER",nil,UnitName("target"))
/stopmacro [help]
/y ~~Misdirecting on %f~~
/cast [@focus,exists] Misdirection

This will whisper your tank every time you change focus targets; feel free to change the message to something witty. This also includes a yell that will announce your misdirection on your focus target.

Yet another useful Misdirection macro application geared towards raiders.

If you have a focus target and your focus target is friendly, cast Misdirection on your focus target. If you have a focus target that is not friendly and your focus has a target and that target is friendly, cast Misdirection on your focus' target. (It will fail here if the focus' target is you.) If you have a target and your target is friendly, cast Misdirection on your target. If you have a target that is not friendly and your target has a target, cast Misdirection on your target's target. Else, if your pet is alive and exists, cast Misdirection on your pet.

#showtooltip Misdirection
/cast [@focus,help][@focustarget,help][@target,help][@targettarget,help][@pet,nodead,exists] Misdirection
And... here are yet TWO more variations for Misdirection with some Focus control.

This macro is a variation of the above macro, but with some Focus management on top.

#show Misdirection
/clearfocus [button:2]
/focus [mod:shift] target
/stopmacro [button:2][mod:shift]
/cast [@focus,help][@focustarget,help][@target,help][@targettarget,help][@pet,nodead,exists] Misdirection

Usage :

  • Normal press of this macro will always do the action just like the macro above.
  • Hold down Shift and use this macro will set your Focus to your current target.
  • Right click on this macro icon will clear your focus target.


And the second version... This version does not perform the target of target checks, but it will auto give you a focus if you don't already have one and it's a friendly target.(without key modifiers) It allows you to change focus target with holding down Shift.

#show Misdirection
/clearfocus [button:2]
/stopmacro [button:2]
/focus [@focus,noexists][mod:shift] target
/stopmacro [help]
/cast [@focus,help][help][@pet,nodead,exists] Misdirection

Usage :

  • If you have no Focus and you target a friendly (usually a Tank in a party/raid), your friendly target will be set as your Focus target.
  • If you already have a Focus target and want to change to another friendly target, hold down Shift and press/click macro while targeting the new target.
  • If you already have a Focus target set and wish to clear it, right click the macro icon.
  • After you are satisfied with your Focus target, either target nothing or an enemy and press/click the macro will perform Misdirection aimed at the Focus target. Never have to switch target in the middle of the boss fight again!
  • If you have no Focus and used the macro while targeting an enemy, it will cast Misdirection to your pet if it's out and alive.

Hunter's Mark Edit

This macro will set a friendly target as your focus, assist your focus if you have one, and cast hunter's mark on an enemy target.

#showtooltip Hunter's Mark
/assist [@focus, exists]
/cast [harm] Hunter's Mark;
/focus [help]


This one will switch to Aspect of the Hawk (or keep Aspect of the Hawk if active already) before placing a Hunter's Mark.

#show Hunter's Mark
/cast !Aspect of the Hawk
/cast Hunter's Mark


Aspect Toggle Macro (With AotPack) Edit

#showtooltip
/cast [mod:shift] !Aspect of the Pack;
/stopmacro [mod:shift]
/castsequence !Aspect of the Hawk, !Aspect of the Cheetah
  • Toggles between Aspect of the Hawk and Aspect of the Cheetah
  • If shift-clicked it will cast Aspect of the Pack


Aspect of the Cheetah / Pack by mouse click Edit

Left-click to cast Aspect of the Cheetah; right-click to cast Aspect of the Pack

/cast [button:2] Aspect of the Pack; Aspect of the Cheetah


Bestial Wrath Edit

Kill Command


Puts a Bestial Wrath into your next Kill Command, governed by a cooldown reset. Allows you to use Kill Command at your discretion, but makes sure that when you can use Bestial Wrath, it automatically utilizes this by changing the bind to it, and autocasting Kill Command right after. Adjust to your cooldowns.

/castsequence reset=84 Bestial Wrath, Kill Command, Kill Command, Kill Command, Kill Command, Kill Command, Kill Command, Kill Command, Kill Command, Kill Command, Kill Command, Kill Command


Intimidation


Similar to the above, but generates more aggro; adjust according to your cooldowns. Note that Intimidation also stuns the opponent.

/castsequence reset=84 Bestial Wrath, Intimidation, Intimidation

Raptor Strike + Wing Clip Edit

This is a very simple macro that queues a Raptor Strike for the next normal melee swing and uses Wing Clip. The stopcasting is used to cancel the Raptor Strike effect if the Wing Clip isn't done. If your Raptor Strike is on cooldown, Wing Clip can be used alone. Although this macro contains two skills, it works because one attacks instantly and the other attacks on the next melee swing.

<raptor strike and wing clip are no longer available in the game.>

/cast Raptor Strike
/cast Wing Clip
/stopcasting

Here is an alternative macro that will que Wing Clip for the next melee strike. It allows you to use Wing Clip if you haven't gotten away already, and resets to Raptor Strike when its ready.

/castsequence reset=6 Raptor Strike, Wing Clip

Clever Trapping Edit

Cut down on the number of buttons you have dedicated to traps. The stopcasting & stopattack will help keep you from breaking your own traps. You can also use Immolation/Explosive. Use the Inv misc questionmark icon.

#showtooltip [modifier:alt] Frost Trap; Freezing Trap
/stopcasting
/stopattack
/cast [modifier:alt] Frost Trap; Freezing Trap


Trap Launcher Edit

!!!For the following macro to work you will need the trap icons on your bars. The Macro will allow you to have your most used traps all in 1 button and the button will change icon depending on what trap you are about to launch - it also requires press it twice to actually work - as doing it without /castsequence will make you pay energy twice for the Trap Launcher.

#showtooltip
/castsequence [nomod] reset=3 Trap Launcher,!Explosive Trap
/castsequence [mod:alt] reset=3 Trap Launcher,!Ice Trap
/castsequence [mod:shift] reset=3 Trap Launcher,!Freezing Trap
/castsequence [mod:ctrl] reset=3 Trap Launcher,!Snake Trap

Alternative macro

#showtooltip
/castsequence [nomod] reset=3 Trap Launcher,!Freezing Trap
/cast [mod:alt]Ice Trap
/cast [mod:shift]Snake Trap
/cast [mod:ctrl]Explosive trap


Simple Tracking Macro Edit

This extremely simple macro can be quite useful for PvP, just press it at the start of a battleground to make sure you're tracking everything you need to be.(Incase you turned anything important off for PvE at some point)

/cast Track Humanoids
/cast Track Beasts
/cast Track Hidden

(Add Track Demons/Elemental if you want, sometimes they get annoying)

Beast Mastery Edit

Beast Mastery "I-Win button" Edit

This macro requires a Beast Mastery specialization with the Bestial Wrath talent learned. It can also use any items with On-Use effects, such as potions, trinkets, and items with specific enchants, such as Hand-Mounted Pyro Rockets.

#showtooltip Bestial Wrath
/use Potion of Speed
/cast Bestial Wrath
/cast Intimidation
/petattack

BM DPS Rotation Macro for Patch 4.0.1 Edit

I made this using an older Hunter macro while in IF testing out rotations to find a steady shot rotation that wouldn't starve for focus while maintaining a solid DPS. I decided not to include Beastial Wrath as it can be activated ondemand and may not always be needed depending on the situation. Also note Multi-Shot is optional depending on the type of fight you're in so don't let this macro get you in trouble by leaving Multi Shot in if threat will be a problem. -=DragonBeard=-

#showtooltip
/castsequence reset=10   Serpent Sting, Steady Shot, Steady Shot, Arcane Shot, Steady Shot, Steady Shot, Steady Shot, Multi-Shot, Steady Shot, Focus Fire
/cast [target=pettarget] Kill Command
/script UIErrorsFrame:Clear

Note: While it does make your hunter simple to use, the above macro would be unsuitable for raiding. Using such a lengthy castsequence the player sacrifices much flexibility and the ability to adapt to the situation - he also has little to no control over levels of focus. Though harder to master, *far* superior DPS can be achieved by careful placement of the most used abilities on the action bar and the practise of a basic rotation.

Around Wikia's network

Random Wiki