Useful macros for shamans

From WoWWiki

Macros
General guides
Macros Beginners Guide Making a macro UI FAQ/Macros and scripts Macro API Category:Macros
Useful macros (by class)

Contents 1 General Shaman Macros 1.1 Anti-Spell Combo 1.2 One Button Weapon Enchants 1.3 One Button Harm or Heal 1.4 Mount Or Wolf 2 Elemental Macros 2.1 Shock Cycling 3 Enhancement Macros 3.1 Failsafe Autoattacking 3.2 Shamanistic Rage and Trinket 3.3 Easy Shields 3.4 Enhancement Rebuff Both Weapons 4 3.2 Restoration Macros 4.1 Cure or purge? 4.2 Modifier-less, One button Multi-targeting heal macro

General Shaman Macros

Anti-Spell Combo

This combo takes advantage of the fact that Wind Shear is not only on a different cooldown to Shocks, but also circumvents global cooldown. Using this macro will both interrupt the target's casting, and cast Purge on them.

/cast Wind Shear
/cast Purge

One Button Weapon Enchants

Shamans use a lot of action bar space for all of their self-enchants. This macro combines all four weapon enchants into a single button that heaves thus when you click it:

1. No Modifier: Windfury Weapon
2. Alt: Rockbiter Weapon
3. Ctrl: Flametongue Weapon
4. Shift: Frostbrand Weapon

/use [nomodifier] Windfury Weapon; [modifier:alt] Rockbiter Weapon; [modifier:ctrl] Flametongue Weapon; [modifier:shift] Frostbrand Weapon

Naturally, spells can be changed around depending on what enchant you like to use. To conserve space in the macro, you don't need the Windfury option until level 30, and at that point you will want to remove Rockbiter from the macro.

One Button Harm or Heal

This simple macro combines a damage-dealing spell with a healing spell. It will never give you an error message from casting a spell on the wrong target, it saves space on your action bar, and gives you access to two spells at once.

/cast [harm] Lightning Bolt; [help] Healing Wave

You can pair damage dealing spells with healing spells however you want. I prefer to match similar spells together to make it easier to use. This example pairs Lightning Bolt with Healing Wave due to their similar cast times. Another example would be Chain Lightning and Chain Heal which share similar cast times, cooldown, and impact multiple targets.

Depending on your spec and role in a party or raid, you may want the macro to display a tooltip. For example, a healer may want to check how much healing his spell does. You can add the showtooltip command to display the healing spell during a mouseover, like this:

#showtooltip Healing Wave
/cast [harm] Lightning Bolt; [help] Healing Wave

You can make this macro for each of your healing spells, saving a slot each time and still giving you extra control over your shaman's abilities.

Mount Or Wolf

This macro will put you on your mount if you're out of combat, and shift you into Ghost Wolf when in combat. You can also right-click on the macro to put yourself in Ghost Wolf form without being necessarily in combat.

#showtooltip
/stopcasting
/cast [stance][combat,nomounted][button:2] Ghost Wolf;Mount Name
/dismount [mounted]

Elemental Macros

Shock Cycling

This macro is designed to economise bar space. Use this if you find you open with Flame Shock, and use Earth Shock as a follow-up before Flame Shock's DoT has passed.

#Showtooltip
/castsequence reset=combat/target/12 Flame Shock, Earth Shock
/startattack [harm]

The macro will cast Flame Shock on the target, then start you fighting the target. When your next shock is avaailable, the macro will cast Earth Shock, unless Flame Shock's DoT has completed. The macro will also reset if you drop out of combat, or change targets. Note that as you advance, and the cooldown on your Shocks becomes low enough thanks to Reverberation and Glyphs, you can add a third shock into the sequence.

Enhancement Macros

Failsafe Autoattacking

Many enhancement shamans use Stormstrike as an opening move, but if Stormstrike is on cooldown, the shaman may find themselves standing around dumbly without attacking. This macro uses /startattack to fix that.

#showtooltip
/cast Stormstrike
/startattack [harm]

Shamans who use a shock spell as an opening move may also find this macro useful, as spells do not activate autoattack.

Shamanistic Rage and Trinket

This macro is designed for those situations when you're surprised and need a burst - both offensive and defensive - to get back into the fight. This requires an at-use Attack Power boosting trinket.

/use (trinket that you have equipped) ex. Platinum Disks of Battle
/cast Shamanistic Rage

Tauren characters have an additional option in that their warstomp racial ability doesn't trigger global cooldown. This means they can add it to the macro - though, because it is channeled slightly, it needs to be put last.

/use (trinket that you have equipped) ex. Platinum Disks of Battle
/cast Shamanistic Rage
/cast Warstomp

Note that Blood Fury can also be used instead of Warstomp, or Blessing of the Naaru.

Easy Shields

This macro allows you to pick your shield using modifiers. Hold shift to cast Water Shield, or use it without holding additional keys for Lightning Shield. Makes shield management a bit easier and saves space on the action bar.

/cast [nomodifier] Lightning Shield; [modifier:shift] Water Shield;

Enhancement Rebuff Both Weapons

If you want a combined macro to rebuff both weapons then use:

#showtooltip 
/castsequence reset=5 Windfury Weapon, Flametongue Weapon;
/castsequence reset=5 16, 17;

However that requires you to rebuff in quick succession and will fail if the main hand is buffed but the off hand isn't. If you prefer a safer option then go with two macros :

#showtooltip 
/cast Windfury Weapon 
/use 16 

for main hand and

#showtooltip 
/cast Flametongue Weapon 
/use 17 

for off-hand.

3.2 Restoration Macros

Cure or purge?

#showtooltip
/cast [target=mouseover,harm,exists] [target=target,harm,nodead] [target=targettarget] Purge
/cast [target=mouseover,help,exists] [target=target,help,nodead] [target=targettarget,help,nodead] [target=player,help,nodead] Cleanse Spirit

This macro is designed to purge and cleanse a target with one key; it is not 100% reliable (for example, if the target is under a Paladin's Divine Shield, the shield will confuse the macro, failing to cleanse the target of a poison.

Modifier-less, One button Multi-targeting heal macro

This macro requires no extra buttons or modifier keys to be pushed in order to operate, only the normal mouse pointer you would use to click on the intended target and the single button you would use to cast the heal normally. This macro puts the heals on an extended priority list that allows you to work different healing assignments with ease. It attempts the following in order, moving to the next if one it is unable to preform the previous action.

• At first...

1. It attempts to cast the intended heal on any friendly target your mouse pointer is hovering over (Or if it is hovering over their party/raid icon)
   • If that fails then...
2. It attempts to cast the heal on your current target if it is friendly and alive.
   • Then if that fails..
3. It attempts to cast the heal on the target of your target if your current target is unfriendly.
   • And finally...
4. It attempts to cast the heal on yourself if none of the previous conditions are met.

#showtooltip HealingSpell
/cast [target=mouseover,help,exists] [target=target,help,nodead] [target=targettarget,help,nodead] [target=player] HealingSpell

This macro can be used with Lesser Healing Wave, Healing Wave, Chain Heal, or any other heal from any other class as well as curative abilities like Cleanse Spirit, Purge, and the like. Just replace 'Healingspell' with the appropriate spell name.