Wowpedia

We have moved to Warcraft Wiki. Click here for information and the new URL.

READ MORE

Wowpedia
Register
Advertisement
Macros
General guides

Macros Beginners Guide
Making a macro
Macro conditionals
Macro commands
Category:Macros

Useful macros by class

Useful macros for death knights Useful macros for demon hunters Useful macros for druids Useful macros for hunters Useful macros for mages Useful macros for monks
Useful macros for paladins Useful macros for priests Useful macros for rogues Useful macros for shamans Useful macros for warlocks Useful macros for warriors

Macro Formatting Guidelines[]

Note: With the release of 6.0.2, many spells have been renamed, and much of the scripted command functionality has been modified. In an effort to keep Wowpedia posts relevant, please re-validate and re-post macros that work in the current version.

Re-Creating Old Macros[]

When re-creating a macro in Useful macros please

  • follow the example format posted below (to get the frame around your macro, add a space before you start it)
  • describe what it does
  • note the version of WoW in which you tested it
  • remove it from the Old Macros page

Example Macro[]

/y Hooray, I made a macro!
  • Use: This yells, "Hooray, I made a macro!"
  • Works in 6.x

How to Customize These Macros[]

Disclaimer[]

The macros in this page are intended for general use. They are not intended to cover all situations, buffs, or items which you, or other players, own. You may need to modify these macros for your specific use.

Included below is a quick-reference guide to the most relevant macro customizations that druids may want to perform. This is not an exhaustive list, as this is not the primary aim of this document. Should you need to perform other customization work which is not part of this quick guide, please refer to Making a Macro. The UI Forums and the Druid Forums on the official World of Warcraft website are also great resources, should you need additional help.

Stance Number Variations 4.0.6[]

Many druid macros make use of the stance modifier to detect which form you are taking. The stance numbers each refer to a Form. Be aware that Ability druid flightform [Flight Form] or Ability druid flightform [Swift Flight Form] will be either stance 5 or 6, depending on the availability of Spell nature forceofnature [Moonkin Form] and Tree of Life (druid ability).

Stance Number Form Notes
Stance 0 Caster Default Stance, never changes
Stance 1 Ability racial bearform [Bear Form] never changes
Stance 2 Ability druid aquaticform [Aquatic Form] never changes
Stance 3 Ability druid catform [Cat Form] never changes
Stance 4 Ability druid travelform [Travel Form] never changes
Stance 5 Spell nature forceofnature [Moonkin Form] or Tree of Life (druid ability) When available, they are stance 5.
Stance 5 or 6 Ability druid flightform [Flight Form] or Ability druid flightform [Swift Flight Form] If Spell nature forceofnature [Moonkin Form] or Tree of Life (druid ability) is available, theses are stance 6. Otherwise, they will be stance 5.

General Customization[]

Questionmark How do I remove audible error messages, such as "Target not in Range"?

-  You can either turn off Error Speech in your Sound & Voice settings, or add the following lines at the beginning and end of the offending macro:

/console Sound_EnableSFX 0
/console Sound_EnableSFX 1

Questionmark How do I activate a trinket, or any other item?

-  Add these lines at the end of your macro to activate a trinket (13 is the top trinket slot, 14 is the bottom slot). For any other equipment or inventory slot, refer to InventorySlotId

/use 13
/use 14

Questionmark How do I set a raid target?

-  The following command will set a skull raid target:

/script SetRaidTarget("target",8)

Notes

  • The number 8 in this line refers to the skull. Refer to Raid_target_icons for the ID of other raid targets.
  • Target can be replaced with any valid unit ID. Refer to UnitId for other valid unit IDs.

Questionmark How do I swap action bars?

-  Nowadays, most action bar mods allow very fine control of action bar paging. However, some might still wish to page bars using macros. In that case, this line will allow you to do that. Change the numbers to the bars you wish to swap.

/swapactionbar 1 2

Shapeshifting and Travel[]

Shadowlands Speed Shifting Macro[]

As of 9.0, the stag part of Travel Form can no longer be ridden by party members. You must either speak to Amurra Thistledew in The Dreamgrove (Legion class order hall in Val'sharah) or to Lorelae Wintersong in Moonglade and purchase Tome of the Wilds: Mount Form. This will teach you a new shapeshifting option called "Mount Form" that is a rideable stag. Glyph of the Doe will affect the appearance of Mount Form, but Glyph of the Cheetah will not.

Once you have acquired this new form, you can use the following macro for a shapeshifting button that is almost identical to how Travel Form worked before 9.0. This macro will:

  • Shift you into Travel Form if any modifier is held (alt, shift, or ctrl).
  • Shift into Travel Form if swimming or not in a group.
  • Shift you into Cat Form if you are indoors and not swimming (for extra speed).
  • Shift you into mount form if you are in a group and can not fly (a second version without this option is listed as well).
  • Change the picture for the macro to reflect the shapeshift form you will use.
    • IMPORTANT NOTE: Although the pathfinder achievements are no longer necessary for flying in WoD or Legion, the pathfinder achievement seems to affect the "flyable" modifier in this macro. If you do not have the pathfinder achievement for BFA or Legion, this macro will behave as though you can not fly in those zones. This is why the macro includes the option to override the macro by holding any modifier key.

Shadowlands Speed Shifting Macro (with Mount Form)

#showtooltip
/cast [modifier] Travel Form, [swimming] Travel Form; [indoors] Cat Form; [noflyable, group] Mount Form(Shapeshift); Travel Form;

Shadowlands Speed Shifting Macro (without Mount Form)

#showtooltip
/cast [modifier] Travel Form, [swimming] Travel Form; [indoors] Cat Form; Travel Form;
  • Tested in 9.0.2


WoD Power Shifting Macro[]

Now that all three travel forms (Flight Form/Swift Flight Form, Travel Form and Aquatic Form) have been all merged into a single Travel Form as of 6.0, a much simpler macro can be used to powershift. This macro will:

  • Shift you into the aquatic version of Travel Form if you are swimming and not in Travel Form
  • Shift you into Cat Form if you are indoors and not in Cat Form
  • Shift you into Travel Form (flight or ground version, depending on location/combat status/training) if you are outdoors and not in Travel Form
  • Shift you into Bear Form if you are in Travel Form or Cat Form (for maximum survivability while power shifting)

WoD Power Shifting Macro

#showtooltip
/cast [swimming,nostance:3] Travel Form; [indoors,nostance:2] Cat Form; [outdoors,nostance:3] Travel Form; [stance:2/3] Bear Form


  • tested in 6.0.3

Travel 4.0.6[]

This macro will select the appropriate travel mode depending on which ones are usable.

Breakdown

  • If mounted, you will be dismounted.
  • While swimming, Ability druid aquaticform [Aquatic Form] will be cast
  • While indoors, Ability druid catform [Cat Form] will be cast.
  • When outdoors and in combat, Ability druid travelform [Travel Form] will be used
  • When CTRL is pressed, Ability druid travelform [Travel Form] will be used.
  • When outdoors, out of combat, and in a zone where you can fly, Ability druid flightform [Swift Flight Form] will be used
  • Otherwise, your Ground Mount is used.

Notes

  • This macro includes a powershift feature to clear snares. It will always choose the most appropriate travel mode while doing so.
  • When Shift is pressed, all forms will be canceled and you will be returned to Caster form.
  • Shifting to Ability druid flightform [Swift Flight Form] while in flight will level you off and make your flight horizontal to the ground.
  • In most cases, the CTRL override for Ability druid travelform [Travel Form] will not be needed, as this macro is able to choose the correct travel mode on its own. There is one exception to this rule. When in battlegrounds, carrying the flag, and not in combat, this macro will default to Swift Stormsaber. Obviously, you will not want to mount if you are carrying the flag. The CTRL override is provided for that purpose.
  • Replace Ground Mount with Ground Mount of choice.
  • Replace Ability druid flightform [Swift Flight Form] with Ability druid flightform [Flight Form] if you do not have Ability druid flightform [Swift Flight Form] yet.
  • You may not have access to all travel mods, depending on your level. Use the macro appropriate for your level. Some minor edits may be needed.
  • The lvl 60 - 85 version of this macro may not work as expected. The flyablecondition only tests to see if you can fly in that zone; it does not test to see if you have the ability to do so. You may want to keep using the lvl 30 version until you have bought the necessary flight licenses.
  • This macro does not take into account the aquatic mount you get in Vashj'ir. With the speed bonus you get in Vashj'ir, and Glyph of Aquatic Form, there is no noticeable speed difference which would warrant a modified version of this macro.

LVL 16

#showtooltip
/cancelform [nostance:0,mod:shift]
/stopmacro [mod:shift]
/cast [swimming] !Aquatic Form; [indoors] !Cat Form; !Travel Form

LVL 20

#showtooltip
/cancelform [nostance:0,mod:shift]
/stopmacro [mod:shift]
/cast [swimming] !Aquatic Form; [indoors] !Cat Form; [combat][mod:CTRL] !Travel Form; Ground Mount
/dismount [mounted]

LVL 60 - 85

#showtooltip
/cancelform [nostance:0,mod:shift]
/stopmacro [mod:shift]
/cast [swimming] !Aquatic Form; [indoors] !Cat Form; [combat][mod:CTRL] !Travel Form; [flyable] !Swift Flight Form; Ground Mount
/dismount [mounted]

Feral Powershift/Travel - 4.0.6[]

This macro will remove snares without taking you out of your current form. This will allow you to avoid being caught in caster form and making you vulnerable to sheep. It has been customized for Feral Druids and includes travel functionality.

Breakdown

  • If mounted, you will be dismounted.
  • If already in Ability racial bearform [Bear Form] or Ability druid catform [Cat Form], using this macro will powershift to clear snares.
  • If you are not in any form, and are in combat, this macro will default to Ability druid catform [Cat Form]
  • If you are not in any form, and are not in combat, or ALT is pressed, this macro will have the same basic functionality as the Travel Macro. It does not support unshifting, at it is already very close to the 255 character limit for macros.

Notes

  • All notes valid for Travel Macro are also valid for this macro.
  • If you are in Bear Form and have Spell holy blessingofstamina [Furor], this macro can be used to get a quick 10 energy.
  • This macro is not meant to be used on its own. While it does support Bear Form powershift, it does not have any way to shift to Bear Form. This macro is meant to be used along with shifting macros such as Bash and Mangle/Ravage.
  • Shifting does not break roots as of 4.0.6


#showtooltip
/cast [form:1, nomod] !Bear Form; [form:3, nomod][combat, nomod] !Cat Form; [swimming] !Aquatic Form; [indoors] !Cat Form; [combat][mod:CTRL] !Travel Form; [flyable] !Swift Flight Form; Ground Mount
/dismount [mounted]

Moonkin Powershift/Travel 4.0.6[]

This is a simple travel and powershift macro for Moonkins.

Breakdown

  • Using this macro will shapeshift you into Spell nature forceofnature [Moonkin Form].
  • If already in Spell nature forceofnature [Moonkin Form], using this macro will powershift to clear roots and snares.
  • When Shift is pressed, all forms will be canceled and you will be returned to Caster form.
  • When CTRL is pressed, the appropriate travel mode will be chosen:

Notes

  • Replace Swift Stormsaber with non-flying mount of choice.
  • Replace Ability druid flightform [Swift Flight Form] with Ability druid flightform [Flight Form] if you do not have Swift Flight Form yet.
  • The noswimming condition is required, as without it, the macro would always powershift Moonkin while indoors and swimming, even if CTRL is held.
/cancelform [nostance:0,mod:shift]
/stopmacro [mod:shift]
/cast [nomod:ctrl][indoors, noswimming] !Moonkin Form; [swimming] !Aquatic Form;  [combat] !Travel Form; [flyable] !Swift Flight Form; Ground Mount
/dismount [mounted]

General[]

Innervate 4.0.6[]

This macro will choose a target and cast Innervate.

Breakdown

  • If you press any of the modifier keys (shift, alt, ctrl), you will be the target of your Innervate.
  • If you are mousing over a friendly target, it will be the Innervate target.
  • If you you have a friendly focus, it will be the Innervate target.
  • If you you have a friendly target, it will be the Innervate target.
  • If you do not have a mouseover target, or a friendly focus or target, you will be the target of your Innervate.

Note:

  • There are multiple versions of this macro. This document is not intended to cover all versions. This version is intended to cover as many situations as possible. You should edit it for your own needs.
#showtooltip
/cast [mod, @player][@mouseover, exists, help][@focus, exists, help][@target, exists, help][@player] Innervate

Faerie Fire 4.0.6[]

This will cast the appropriate Faerie Fire, depending on your Form, at your target, or any target over which you are mousing.

#showtooltip
/cast [stance:1/3, exists][stance:1/3, @mouseover,harm,nodead] Faerie Fire (Feral)(Feral); [exists][@mouseover,harm,nodead] Faerie Fire

Dash 4.0.6[]

This will shapeshift to Cat Form and then use Dash.

All Races:

#Showtooltip Dash(Cat Form)
/cast [nostance:3] Cat Form(Shapeshift); Dash(Cat Form)

Worgen version:

  • This macro will cast Dash, or Darkflight if Dash is on cooldown.
  • Dash is placed first as it will be a root break in patch 4.1. This also allows Darkflight to remains available in Caster or Bear Form.
  • The 144 time value on the reset assumes that Dash is glyphed.
#Showtooltip
/castsequence [nostance:3] Cat Form(Shapeshift); reset=144 Dash(Cat Form), Darkflight(Racial)

"Focus" Macros[]

These 2 macros were designed to be a portable "Crowd Control and Assist" solution for PvE and PvP settings. They were built with a good Assist and Focus scheme to support those activities. They can be used individually, or in pair, without conflict.

Crowd Control 4.0.6[]

This macro is meant to be used for Crowd Control.

This focus macro is designed to be used with Crowd Control abilities. It will cast your Crowd Control spell on your focus, your mouseover target, your target, or on your friendly target's target.

Breakdown

  • Interupt your current spell cast to give priority to your Crowd Control.
  • If CTRL is pressed, or if you do not have a focus, set focus to...
    • The target you are mousing over, if hostile.
    • Your target, if hostile.
  • Cast your spell on...
    • Your focus if hostile
    • Your mouseover if hostile
    • Your target if hostile
    • Your target's target if hostile

Notes

  • This macro can be used as a template for almost any spell.
  • This macro has been made so that it won't override a helpful assist focus.
  • This macro supports either direct targeting, or mouseover. Mouseover has priority.
  • If you already have a focus, you must press Ctrl in order to focus a hostile player for Crowd Control.
#showtooltip Cyclone
/stopcasting
/focus [mod:ctrl, @mouseover, harm][mod:ctrl, harm];[@focus, exists] focus;[@mouseover, harm][harm]
/cast [@focus, harm][@mouseover, harm, nodead][@target, harm][@targettarget, harm] Cyclone

Assist 4.0.6[]

Temporairly unavailable, found bugs and slight functionality problems, currently testing a new version which will be edited ASAP.


Smart Feral Shape[]

  • Some macros will shapeshift to either Bear Form or Cat Form if you are not already in either Form. Cat Form is the preferred form in most cases.
  • They are intended to be buttons that will cast the appropriate spell in Cat or Bear Form in a setup which does not page.
  • Use the Skull Bash macro as a template, if you need to create other similar macros.

Skull Bash - 4.0.6[]

This macro will cast the appropriate Skull Bash spell, depending on whether you are in Cat or Bear Form.

Breakdown

  • If not in Cat Form or Bear form, this macro will Shapeshift to Cat Form.
  • If in Cat Form or Bear From, this will cast the appropriate Skull Bash Spell.
#showtooltip [stance:1] Skull Bash(Bear Form); Skull Bash(Cat Form)
/cast [nostance:1/3] Cat Form; [stance:3] Skull Bash(Cat Form); Skull Bash(Bear Form)

Mouseover Charge 4.0.6[]

This macro will cast the appropriate Feral Charge spell.

Breakdown

  • If mousing over a target, it will be chosen as the target of the charge, otherwise, this will check to see if you currently have a target. If you don't, this will fail. A mouseover target has priority over your currently selected target.
  • If not in Cat Form or Bear form, this macro will Shapeshift to Cat Form.
  • If in Cat Form or Bear From, this will cast the appropriate Charge Spell.
  • If in Cat Form after performing a charge, the next use of this macro will cast Ravage

Note:

  • To be able to benefit from the free Ravage after a Feral Charge in Cat Form, you will need the Stampede talent.
#showtooltip
/castsequence [nostealth, nostance:1/3] Cat Form(Shapeshift); [stance:1,@mouseover,exists,harm,nodead][stance:1,@target] Feral Charge(Bear Form); [@mouseover,exists,harm,nodead][@target] Feral Charge(Cat Form), Ravage!

Tiger's Fury/Enrage/Berserk 4.0.6[]

This macro will cast Tiger's Fury in Cat Form, Enrage in Bear Form, or Berserk if shift is held.

/cast [modifier:shift,stance:1/3] Berserk; [stance:3]Tiger's Fury; [stance:1]Enrage

Feral (Cat)[]

  • These macros will shapeshift to Cat Form if you are not in Cat form
  • Most of these macros will cast Prowl if you are not in combat and not already prowling.
  • They are intended to be spammable buttons to be used with an interface setup which does not page.

Maim 4.0.6[]

This macro will cast Maim.

Note:

  • If you are not in Cat Form and have no combo points, using this macro will Shapeshift to Cat Form, but will fail to cast Maim.
  • The code of this macro serves as a base for most of the Cat Form macros presented here. It can be used with almost any of Cat Form's spells.
#showtooltip Maim(Cat Form)
/cast [nostance:3] Cat Form(Shapeshift); [nostealth, nocombat] !Prowl(Cat Form); Maim(Cat Form)

Mangle/Ravage 4.0.6[]

This macro will cast Mangle (or Ravage, if prowling).

#showtooltip [stealth] Ravage(Cat Form); Mangle(Cat Form)
/cast [nostance:3] Cat Form(Shapeshift); [nostealth, nocombat] !Prowl(Cat Form); [stealth] Ravage; Mangle(Cat Form)

Shred/Pounce 4.0.6[]

This macro will cast Shred (or Pounce, if prowling).

#showtooltip [stealth] Pounce(Cat Form); Shred(Cat Form)
/cast [nostance:3] Cat Form(Shapeshift); [nostealth, nocombat] !Prowl(Cat Form); [stealth] Pounce(Cat Form); Shred(Cat Form)

Night Elf Pounce 4.0.6[]

This macro will cast Pounce if prowling. While in combat, the first use of this macro will cast Shadowmeld, the second will cast Pounce.

Breakdown

  • If you are in combat, Shadowmeld will be cast.
  • If you are Shadowmelded or Prowling, Pounce will be cast.
  • This macro can also be used to re-stealth mid fight. Be aware that it does take about half a second for the UI to detect that you are out of combat once Shadowmeld has been cast. This macro works much better as an in-combat Pounce, because the UI is much faster to detect stealth, and Shadowmeld does not burn the Global Cooldown. You may have to press this button a few times before you enter prowl. You will want to put some distance between you and your opponent. You will also want to make sure that you do not have any dots on you before you attempt this. Make sure you do not move until you are prowling.

Notes

  • This macro is aimed at Night Elves. If you aren't a Night Elf, I would recommend using the Shred/Pounce version of this macro.
  • This macro will also work with Ravage, although you will have to be behind the target before you Shadowmeld, in order to be able to Ravage.
#showtooltip
/cast [nostance:3] Cat Form(Shapeshift); [nostealth, nocombat] !Prowl(Cat Form); [nostealth, combat] Shadowmeld(Racial); [stealth] Pounce(Cat Form)

Charge -> Ravage 4.0.6[]

This macro will cast Feral Charge and then follow with Ravage.

Notes

  • These macros are intended to be used with the talent "Stampede" to benefit from the free Ravage after a Charge.
  • The ! after Ravage is required for these macros to work properly. In your spellbook Ravage is a single spell, but the UI sees Ravage and Ravage! as 2 different spells. Ravage is only usable while stealthed, and Ravage! is usable while the Stampede buff is up.

Charge -> Ravage

#showtooltip
/castsequence [nostance:3] Cat Form(Shapeshift); reset=10 [@mouseover, exists, harm, nodead][@target] Feral Charge(Cat Form), Ravage!

Pounce/Charge -> Ravage

  • Same as the above, but with the added twist that it will cast Pounce instead if Stealthed.
#showtooltip
/castsequence [nostance:3] Cat Form(Shapeshift); [nostealth, nocombat] !Prowl(Cat Form); [stealth] Pounce(Cat Form); reset=10 [@mouseover, exists, harm, nodead][@target] Feral Charge(Cat Form), Ravage!

Feral (Bear)[]

Notes

  • Theses macros will shapeshift to Bear Form if you are not in Bear form
  • They are intended as spamable buttons to be used with an interface setup which does not not page.

Bash- 4.0.6[]

This macro macro will shapeshift to Bear Form if not in bear form and cast Bash.

#showtooltip Bash
/cast [nostance:1] Bear Form(Shapeshift); Bash

Taunt - 4.0.6[]

This macro will shapeshift to Bear Form if not in bear form and cast Growl.

#showtooltip Growl(Bear Form)
/cast [nostance:1] Bear Form(Shapeshift); Growl(Bear Form)

Gowl / Chalenging Roar - 4.0.6[]

This macro will shapeshift to bear form if not in bear form and cast Growl or Challenging Roar if shift is held.

#showtooltip
/cast [nostance:1] Bear Form(Shapeshift); [mod:shift] Challenging Roar; Growl

Survival - 4.0.6[]

This macro will use all of your survival cooldowns with one press.

Notes

  • This macro is not optimal. In most situations, survival cooldowns are best staggered in order to extend your survival time.
  • All 3 abilities will activate simultaneously.
  • You may want to add a /use 13 or /use 14 line to this macro if you have a tanking trinket.
  • If you have potions, or healthstones at your disposal, you may want to add a /use line for those.
#showtooltip Frenzied Regeneration(Bear Form)
/cancelaura Enrage
/cast Barkskin
/cast [stance:1] Enrage(Bear Form); Bear Form(Shapeshift)
/cast [stance:1] Survival Instincts(Cat or Bear Form)
/cast [stance:1] Frenzied Regeneration(Bear Form)

Savage Defense - 5.0.5[]

This macro will include Savage Defense (45% dodge ability) on Guardian Druids every time the button it's linked to is pressed.

Notes:

  • You'll probably want to add this to (at least) Lacerate, Thrash, Mangle, and Swipe.
  • Pressing the button will fire SD, holding any modifier key (ctrl, alt, shift) will bypass SD. You can reverse this behavior by changing [nomod] to [mod] below.
  • Change "Mangle" below (in both places, to keep the tooltips in line with the ability) to whatever is appropriate for the button you want (you'll need a total of 4 macros to do all the buttons above)
  • The UIErrors bit keeps you from getting spammed with "not enough rage" or "not ready yet" on screen, but the voice prompt will still go off (this can be turned off in your settings).
#showtooltip Mangle
/script UIErrorsFrame:Hide()
/cast [nomod] Savage Defense
/script UIErrorsFrame:Clear()
/script UIErrorsFrame:Show()
/cast Mangle

Moonkin[]

Wild Mushroom 4.0.6[]

This macro will cast wild mushroom. When shift is held, it will detonate the mushrooms.

#showtooltip
/cast [mod:shift] Wild Mushroom: Detonate; Wild Mushroom

Call out Innervate to Party/Raid respectively 3.1.1[]

#showtooltip 
/stopmacro [nohelp,dead] 
/run c="Innervating %t"if UnitInRaid("player")then SendChatMessage(c, "RAID")elseif GetNumPartyMembers()>0 then SendChatMessage(c, "PARTY")end 
/cast Innervate
  • Use: This macro will send a message to the appropriate channel (raid if you're in a raid, party if you're in a party, or no message at all if you're soloing) declaring who it is that just got your innervate spell.
  • Will send message even if self-cast or cast does not go off due to range or skill being on cooldown.

Cyclone / Roots 3.1.1[]

#showtooltip
/use [mod:alt] Entangling Roots; [mod:shift] Cyclone; [target=focus, exists] Cyclone; Cyclone
  • This macro is very imperfect. Please improve or preferably give alternatives.

Thorns 4.0.6[]

This macro casts thorns on the most apropriate target.

Breakdown

  • In order of priority, cast Thorns on...
    • Friendly mouseover
    • Friendly focus
    • Friendly target
    • Friendly mouseover's target
    • Friendly focus' target
    • Friendly target's target
    • Yourself

Notes

  • Depending on your use of this macro, you might want to remove some target options or reorder them.
#showtooltip Thorns
/cast [@mouseover,help][@focus,help][help][@mouseovertarget,help][@focustarget,help][@targettarget,help][@player] Thorns

Resto[]

A lot of macros in this section make use of mouseover. The mouseover target is simply a target which is under your mouse pointer. This can be the frame of any friendly unit in your UI, or a friendly player you are mousing over in your play area. This does not change your current target.

Hover healing[]

This macro will cast Spell nature healingtouch [Healing Touch] either on your mouseover target, your target, or yourself.

Notes

  • This macro can be used as a template for any healing spell you might want to cast as a mouseover.
/cast [target=mouseover,help,nodead][help][target=player] Healing Touch

Rebirth / Revive[]

This macro will cast the appropriate resurrection spell depending on if your in combat or not.

Note

  • You can announce which target you are resurrecting by adding the following line. /say I am resurrecting %t Do note that <no target> will be listed when you are simply mousing over the target you want to res.
#showtooltip
/cast [@mouseover,help,combat][help, combat] Rebirth ; [@mouseover,help][help] Revive

Multibox Battle Rez Macro 4.0.1[]

#showtooltip Rebirth()
/stopcasting
/target [target=Player1, dead] [target=Player2, dead] [target=Player3, dead] [target=Player4, dead]
/castsequence [exists,noharm,dead] reset=600 Rebirth(),,
1st line: Forces the UI to show the Rebirth tooltip (the thing that pops up when you hover your mouse over a -spell/item/etc)
2nd line: Stops any spellcasting in progress
3rd line: This is the targeting line, it automatically cycles through my guys and finds the 1st dead one on the list, then selects him
4th line: Before casting the spell and wasting a precious 10min CD for a brez, it makes sure the target exists, is friendly, and is, in fact, actually dead and not just pretending.

4th line: the reset timer is set to 10 minutes and it's put on a cast sequence so that each of the 3 guys i have it on casts it in order

1st guy: Rebirth(),,
2nd guy: ,Rebirth(),
3rd guy: ,,Rebirth()

What this does is cause each of the different druids to cast nothing and move on to the next "spell" in the cast sequence, or cast Rebirth

In a nutshell, you press one button when one of your guys keels over and it auto-selects, auto-cast, and auto-cycles all in one button press. If you have time to set it up or have a consistant 5/10/25 man group, you can replace the Player# names with your group members for a quick brez.

Advertisement