Useful macros for mages

Macros
General guides
Macros Beginners Guide Making a macro Macro conditionals Macro commands Category:Macros
Useful macros by class

Combat

Pyroblast or Fireball

Casts Pyro if you're not in combat (as an opener), Fireball otherwise

/cast [nocombat] Pyroblast; Fireball

Arcane Explosion

When out of combat it will cast Arcane Explosion rank 1 for two reasons: It is useful for looking for stealthed enemies to conserve mana, as well as being helpful when protecting points of interest in PvP. In combat it will cast highest Arcane Explosion. It has /stopcasting at the end so that it doesn't *hold* casting and makes you unable to cast any other spell, which happens often when you AOE so many mobs and lag.

#Showtooltip Arcane Explosion
/cast [nocombat] Arcane Explosion(Rank 1); Arcane Explosion
/stopcasting

NOTE: Sometimes mashing the button really fast is not a good idea, especially in really high latency. For best results press it once per second only.

Frost Nova / Cone of Cold

This will cast Frost Nova with your first press, then Cone of Cold on your second. This macro will then reset itself after 24 seconds.

/castsequence reset=24 Frost Nova, Cone of Cold

Frost Nova / Cold Snap

This will cast frost nova on first press. If frost nova is still in cool down it will cast cold snap on second press, and it will cast frost nova on third press. The stop casting is in case you want to use it to interrupt another spell(ie they run in close while casting frost bolt).

/stopcasting
/castsequence reset=21 Frost Nova, Cold Snap

Ice Block / Cold Snap

This will cast Ice Block on first press. If Ice Block is still in cool down it will cast Cold Snap on second press, and it will cast Ice Block on third press. This useful so that ensures if Ice Block is on cooldown and Cold Snap is up, you can Ice Block again on the same button. Also it is worth noting you can spam this button and Ice Block will stay on unless you manually click off the buff.

/stopcasting
/castsequence reset=240 Ice Block, Cold Snap

PoM, AP, Trinkets, and spell

#show Pyroblast
/cast Presence of Mind
/stopcasting
/cast Arcane Power
/stopcasting
/use 13
/use 14
/stopcasting
/cast Pyroblast

Use 13 and 14 is if you got a trinket that is usable and does damage or type name of Trinket. Change Pyroblast to desired spell. (/cast Vengeance of the Illidari)

Water Elemental Nova

Since the Water Elemental's ranged nova is currently named Frost Nova you can't use /cast Frost Nova because you have a spell of that name. You can use /click to avoid this.

/cast [nopet] Summon Water Elemental
/click [pet] PetActionButton5

Frost Nova and Pet Frost Nova

Very simple macro that makes you cast Pet Frost Nova if normal Frost Nova is on cooldown. This does give that annoying message/sound saying cant cast that yet but atleast it works.

/cast Frost Nova
/click [pet] PetActionButton5

Quick Counterspell

Most people complain about having to cancel their current spells and then hitting Counterspell. This macro does it for you. It cancels any spell and instantly casts Counterspell.

#showtooltip Counterspell
/stopcasting
/cast Counterspell

Trinket + Casting

There are two versions, one where you can button mash to cast your spells, another where you can click once to activate and cast. These macros assume you have two trinkets that have activation cooldowns, remove one of the /use lines to only use a single trinket. The top trinket slot is "13" and the bottom is "14".

-- Button Mashing Version --

This will activate the top trinket first, then the bottom trinket, then if both trinkets are on cooldown it will cast frostbolt. I mash this button to activate my ZHC/ToEP while chain casting frostbolts

 #show Frostbolt
 /use 13
 /use 14
 /cast Frostbolt

This will Hide the Error massage, but not the sound. (Shift Click your trinkets in place of, or type name of.)

#show Frostbolt
/script UIErrorsFrame:Hide()
/cast Vengeance of the Illidari
/cast Glowing Crystal Insignia
/cast Frostbolt(Rank 13)

-- NON-Button Mashing Version --

This will activate the top trinket first, then the bottom trinket, then if both trinkets are on cooldown it will cast frostbolt. If you hit this button while you are casting it will restart the spellcast, to use this macro effectively only use this when you are not casting (many mages prefer to mash a button as above).

 #show Frostbolt
 /use 13
 /stopcasting
 /use 14
 /stopcasting
 /cast Frostbolt

-- NON-Button Mashing Version with no cooldown error messages --

This is the same as the above, but suppresses visual errors related to the trinkets/spells (you have to Sound Options -> Untick Enable Error Speech to disable the audible errors). The example calls whichever trinket is available, combustion if it's available and then Fireball. You will only ever see errors if the Fireball spell has a problem (out of range, etc)

 #showtooltip Fireball
 /script UIErrorsFrame:Hide()
 /use Glowing Crystal Insignia
 /stopcasting
 /use Terokkar Tablet of Vim
 /stopcasting
 /cast Combustion
 /stopcasting
 /script UIErrorsFrame:Clear()
 /script UIErrorsFrame:Show()
 /cast Fireball

Quick Ice Barrier

Stops current cast in progress and casts Ice Barrier with one click.

#showtooltip Ice Barrier
/stopcasting
/cast Ice Barrier

Anti Grounding Totem Ice Lance

• When used, this macro will cast Ice Lance on the nearest Grounding Totem without you loosing your current target.
• If no Grounding Totem exists it will simply cast Ice Lance on your current target.

#showtooltip Ice Lance
/stopcasting
/focus target
/target [exists] Grounding Totem
/cast Ice Lance
/target focus
/clearfocus

Polymorph

Enemy Sex, Level, Name

This macro will cast Polymorph if the target is hostile, then stop the macro if the target is NOT hostile (i.e. if the polymorph didn't go off). Then emotes that it's target has been Sheeped, the sex and level of the target. Note that because of the '/stopmacro' command, if the target was not sheeped, the party would not be sent a tell (thus cutting down on unnecessary spam). You can change EMOTE in the macro to be PARTY for party chat etc.

/cast [harm] Polymorph
/stopmacro [noharm]
/script if UnitSex("target") == 1 then SendChatMessage("Sheeping Female " .. UnitLevel("target") .. " %t","EMOTE") else SendChatMessage("Sheeping Male " .. UnitLevel("target") .. " %t", "EMOTE"); end

sample output: Player Sheeping sex Level Target Name

Focus

Will always polymorph your focus target

/cast [target=focus] Polymorph

Easy Sheep- right-click instant re-sheep

Left-click to sheep and set the target as your focus. Right click to instantly re-sheep your focus, without having to leave the target you are fighting. No need to turn or anything. If you are holding shift when right or left clicking, it will not focus or sheep anything, but instead target your focus and clear your focus- do this when the other target is dead and you're ready to kill the sheep.

/focus [button:1]
/cast [button:1,nomodifier:shift] Polymorph; [target=focus,exists,button:2,nomodifier:shift] Polymorph
/stopmacro [nomodifier:shift]
/target focus
/clearfocus

I didn't dare to go edit the original authors macro but I cleaned up the macro a bit.

/focus [button:1]
/cast [button:1, nomodifier] Polymorph; [button:2, nomodifier, target=focus, exists] Polymorph
/stopmacro [nomodifier:shift]
/target focus
/clearfocus

Focus Sheep Simplified

The above macro wasn't working for me no matter how many times I retried it, rechecked that I had the code from above, or attempted to modify it. Instead I simply took a seduction macro from my warlock and changed it a little for Polymorph. First click will set your target as focus and Polymorph it. Any subsequent clicking (left-click) will Polymorph the same target no matter what you're currently targeting. If you wish to Polymorph a new target, simply hold down on shift (or alt or ctrl, whichever you prefer to place in this spot) once you've selected your new target and click the button. It will clear the old focus first and continue to do all the rest of the macro.

#show Polymorph
/clearfocus [modifier:shift]
/focus [target=focus,noexists]; [target=focus,dead]
/clearfocus [target=focus,help]
/stopcasting
/cast [target=focus,exists,harm] Polymorph; Polymorph

If you do not have a previous focus or if your focus is now dead, this will make your target the focus. If your focus is now helpful to you (friendly) then it will clear the focus for you. Perhaps most importantly, this will stop whatever else you're casting in order to resheep your focus when you need it.

Random

1. If the target can be polymophed, one of the listed spells will be chosen.
2. If the target can not be polymorphed, stop macro processing.
3. Otherwise, send an emote stating polymorph is in progress.

/castrandom [harm] Polymorph(Rank 4), Polymorph: Pig, Polymorph: Turtle
/stopmacro [noharm]
/emote randomly polymorphs %t.

Focus, Set Focus if unset

1. If you don't have a focus, focus your current target.
2. If the target is hostile, Polymorph it.
3. If the Polymorph succeeded, warn your party.

/focus [target=focus, noexists] target
/cast [target=focus, exists, harm] Polymorph
/stopmacro [noharm]
/p Sheeping %t! DO NOT TOUCH!

Full Polymorph/Focus Macro

This polymorph macro will do the following:

1. Clear your focus if your old focus target is dead
2. Clear your focus if your old focus target doesn't exist anymore
3. Set your focus on what you have targeted if you don't have a focus already
4. Place a Star marker over the head of the focus target (if you are group/raid leader/assistant)
5. Polymorph the Focus target
6. If you are grouped, announce the sheeping to the group.

This allows one button to do the whole sheeping process without the need for a separate /clearfocus button (though an additional macro that does a /script SetRaidTarget("focus",0) and then a /clearfocus would be useful to let the group know the sheep is free game now might be useful)

/clearfocus [target=focus,dead][target=focus,noexists]
/focus [target=focus,noexists]
/script SetRaidTarget("focus", 1)
/cast [target=focus] Polymorph
/stopmacro [nogroup]
/p --== Sheeping and Marking "%T" ==--

As of 2.1, you can also use %f to insert your focus name in chat just like %t inserts your target. Thus, to alert your party that you are sheeping (or re-sheeping) your focus and not your target, try this instead of the last line above:

/p --== Sheeping and Marking "%f" ==--

This macro may cause you trouble with your sheep target being "too sticky", like when you need to switch Poly targets before your original Poly target is dead. Adding the following line to the beginning of the macro will allow you to press Shift to sheep your current target regardless of where the focus was set.

/clearfocus [modifier:shift]

Paste

 /clearfocus [button:2] 

at the top of the macro to right click (unfocus) and sheep something diffrent.

Target Tracking

This polymorph macro will do the following:

1. Left-Click: Set saved target to current target and sheep it
2. Right-Click: sheep saved target (do not change current focus)
3. Shift-Left-Click: set focus to saved target

/focus [button:1]
/cast [button:1,nomodifier:shift] Polymorph; [target=focus,exists,button:2,nomodifier:shift] Polymorph
/stopmacro [nomodifier:shift]
/target focus

Target Tracking with Instant Crowd Control Option

This polymorph macro will do the following:

1. Left-Click: Set saved target to current target and sheep it
2. Right-Click: sheep saved target (do not change current focus)
3. Shift-Left-Click (first click): set saved target to focus, cast Presence of Mind
4. Shift-Left-Click (second click): set saved target to focus, sheep it
5. Shift-Right-Click (first click): set focus to saved target, cast Presence of Mind
6. Shift-Right-Click (second click): set focus to saved target, sheep it

/focus [button:1]
/cast [button:1,nomodifier:shift] Polymorph; [target=focus,exists,button:2,nomodifier:shift] Polymorph
/stopmacro [nomodifier:shift]
/target [button:2] focus
/castsequence Presence of Mind, Polymorph

Super Polymorph

This macro will sheep and put focus on your target if your holding down CTRL while pressing sheep and sheep focus if you currently have a target focused without targeting it or act as normal sheep when you don't have a targeted focus and don't press down CTRL.

/focus [modifier:ctrl]
/castrandom [target=focus] Polymorph(Rank4), Polymorph: Pig, Polymorph: Turtle;

Conjuring, Food and drink

Conjure/Consume Food, Water, and Gem all in one button

Left click to conjure, right click to consume. Click normally to conjure/drink water, shift-click to conjure/eat food, and control-click to conjure/consume mana gem (replace names of items with whatever the name of what you are currently conjuring is) If you use the ? Icon with this macro, the icon will automatically change based on what buttons you are holding.

/cast [button:1,nomodifier]Conjure Water;[button:1,modifier:shift]Conjure Food;[button:1,modifier:ctrl]Conjure Mana Jade;
/use [button:2,nomodifier]Conjured Spring Water;[button:2,modifier:shift]Conjured Pumpernickel;[button:2,modifier:ctrl]Mana Jade;

Another conjure/consume food/water/gem in one button

A right click will cycle through conjuring food, water, and a mana gem, resetting the cycle after 8 seconds. A right click with shift held will conjure a mana gem, regardless of castsequence position. Left clicking will drink with no modifiers, eat with control, and use the mana gem with shift. Note that this is MUCH more useful with the question mark icon.

/cast [modifier:alt]Conjure Mana Agate
/castsequence [nomodifier,button:2] reset=8 Conjure Water,Conjure Food,Conjure Mana Agate
/stopmacro [button:2]
/use [nomodifier]Conjured Purified Water;[modifier:ctrl]Conjured Rye;[modifier:shift]Mana Agate

Eating and drinking

It's an easy macro if you want to eat and drink with a single click.

/use Conjured Crystal Water
/use Conjured Cinnamon Roll

Conjure or eat/drink

You can condense conjuring and drinking onto a single button using click-logic. In this macro, right-clicks summon water, and left-clicks to use it. The "#show" command will display the count of waters in your inventory on the button face, and if you use the "?" macro icon, it will also show the water-bottle icon on your tool-bar.

#show Conjured Crystal Water
/cast [button:2] Conjure Water
/use [button:1] Conjured Crystal Water

Slightly less useful conjure or eat/drink

this is an easy conjure/use macro for mages, it needs to be mouse clicked though ( anything after "-" is comments)

#show none - so that your UI dont get confused since we got 2 useable items
/use [nomodifier:alt,button:1] <add conjured food name here> - left click = eat food
/use [nomodifier:alt,button:2] <add conjured water name here> - right click = drink water
/cast [modifier:alt, button:1] Conjure Food - alt+left click = conjure highest rank food
/cast [modifier:alt,button:2] Conjure Water - alt+right click = conjure highest rank water

The same logic can be used for food or mana gems, just substitute the names as appropriate. Obviously, replace with the name of the highest-rank item you can conjure.

Conjure Mana Gems

Here is another easy conjure macro that you can use to conjure all 5 gems by just hitting the button 4 times in a row (remove any gems that you dont have yet or that you dont want to make)

/castsequence reset=45 Conjure Mana Emerald, Conjure Mana Ruby, Conjure Mana Citrine, Conjure Mana Jade, Conjure Mana Agate

If you like to have one button per gem for conjuring and casting you can use this macro for each of your gems. Rightclicking it conjures the gem. Any other way of activating the macro (button press or leftclick or something) uses the gem. Of crouse your replace the gem name with the gem you wanted to use. Downside is that if you use the questionmark icon for the macro, it only shows the gem icon if you have it in your inventory. The gem icon turns into a red questionmark when you log in or zone while not having the gem on you. Hope this gets fixed soon. Alternatively, you can select a fixed macro icon that resembles the gem.

#show Mana Citrine
/cast [button:2] Conjure Mana Citrine
/stopmacro [button:2]
/use Mana Citrine

Merely replacing "#show Mana Citrine" with "#show Conjure Mana Citrine" works as well.

Conjure/Use Mana Gem

This macro will conjure a mana gem if you do not already have one, or use one if you do:

#show Mana Ruby
/use Mana Ruby
/cast [nocombat] Conjure Mana Ruby

Replace "Mana Ruby" with whatever your highest level of mana gem is. The "nocombat" conditional ensures that you do not use the gem then immediately try to conjure another one while you are in a hot situation.

Other utility

Mount and keep going

This macro is designed to let you keep running through stuff you don't want to fight without taking damage (and thus not being Dazed). It will always mount you, but if you are targeting something dangerous, it will put up [Mana Shield] first.

#show Chestnut Mare Bridle (or whatever your mount item is)
/cast [nomounted,harm] Mana Shield
/stopcasting
/use Chestnut Mare Bridle (or whatever your mount item is)

Buffing

By clicking the left mousebutton you buff yourself, by clicking the right mousebutton you buff your current target (the default way). You can also change the spell ('Arcane Intellect' used in the example) to whatever you like (i.e. 'Remove Lesser Curse').

 #Showtooltip Arcane Intellect
 /cast [target=player,button:1] Arcane Intellect
 /cast [button:2] Arcane Intellect

Alternately you can use this macro for the similar effect. This will cast AI on self on right click, your target on left click, and your target's party if you are in a group (party/raid) and are holding the ctrl key on left click (mainly useful for not wasting your arcane powder unnecessarily)

 #Showtooltip Arcane Intellect
 /cast [target=player,button:2] Arcane Intellect
 /cast [button:1] Arcane Intellect
 /cast [modifier:ctrl,group,button:1] Arcane Brilliance

You can also use this one. Casts AI on left click, AB on right click. Also respects alt selfcast, and shows the amount of arcane powder left on the macro icon. Just select the Arcane Brilliance icon from the macro interface.

 #show Arcane Powder
 /cast [button:2, modifier:alt, target=player] Arcane Brilliance; [button:2] Arcane Brilliance; [modifier:alt, target=player] Arcane Intellect; Arcane Intellect

Better slow fall

It simply makes you slowfall but it dismounts you first. If you lack the manual dexterity to dismount and then slowfall when you accidentally drop down a cliff, this macro will help you lots. Also, this thing shows the number of light feathers you have left on the macro icon. Note: you will need to press this button twice to dismount and slowfall! Failure to do so in combination with un'goro or flying mounts can have bad consequences.

#show Light Feather
/dismount
/cast Slow Fall

Portal/Teleport on one button

Leftclick teleports you, rightclick summons a portal. The macro shows the amount of teleport stones you have left. Select a custom icon for this one. All the city icons are in the default list. Of course, you adjust the city name to suit your needs.

#show Rune of Portals
/cast [button:2] Portal: Shattrath; Teleport: Shattrath

As of patch 2.1 not only will buttons display the number of reagents available for spells but macros that select different spells will change in real time to show which will be cast. The following macro will teleport you if you are alone and will open a portal if you are in a party or raid, unless you override it by holding down a modifier key (shift/ctrl/alt). Use the red question mark icon to see which spell will be cast when you use the macro.

/cast [group,nomodifier] Portal: Shattrath; Teleport: Shattrath
/stopmacro [nogroup][modifier]
/p << Shattrath Portal Incoming >>

Portal/Teleport and announce to Raid/Party in one button

Leftclick teleports you, rightclick summons a portal, middle button click announces to raid or party that you're creating a portal. Very similar to the macro above.

/cast [button:2/3] Portal: Shattrath; Teleport: Shattrath
/stopmacro [button:1/2]
/script local C; if(GetNumRaidMembers()==0) then C = "PARTY" else C = "RAID" end SendChatMessage("Opening Portal to [Shattrath City], Enjoy your trip.", C)

All 3 armors on one button

Left click for Molten Armor, right click for Frost Armor, and alt-click for Mage Armor. Very handy for conserving hotbar space and the like. You can edit the first line to have it display whichever armor's tooltip you prefer, simply change the name of the spell.

#showtooltip Molten Armor;
/cast [button:2] Frost Armor; [nomodifier:alt] Molten Armor; Mage Armor;

Grouping and raiding

Easy Remove Curse Macro

This macro makes it so you can easily remove curses from party members by continually clicking the macro button. The first click will target you, the second will target the closest party member to you. This continues to all party members within range.

For party:

/targetparty
/cast Remove Lesser Curse

For raid:

/targetraid
/cast Remove Lesser Curse

Hover-Target Decurse

This macro comes from the Discord Mods forum and is extremely useful for raiding, allowing you to decurse a member of your party/raid without having target them. Just hover your mouse over the person's frame in the raid window and hit the key that binds this macro. When using a raid window tuned to show who is in need of decursing (CT Raid comes to mind) this is makes for extremely fast decursing without having to change targets.

/cast [target=mouseover] Remove Lesser Curse

Arcane Spec Macros

With the advent of the arcane spec becoming viable (ABx3->AM->scorch/fireblast rotation) with 2 part Tirisfal Regalia pieces, not casting while channeling arcane missiles needs to be linked to the vast majority of your spells. This is due to arcane blast being a 7 second "buff/debuff" therefore only having .5 seconds of latency & downtime between the last two spells of the rotation and again casting arcane blast.

This macro will make it so if you hit the arcane missiles key while casting arcane missiles, nothing happens, but if you are not casting them then you will begin to cast them.

#Showtooltip Arcane Missiles
/cast [nochanneling:Arcane Missiles] Arcane Missiles

This macro allows you to spam a non-channeled spellkey while channeling arcane missiles and not interrupt the channel (trinket included to show you can also add them in)

#Showtooltip Arcane Blast
/use [nochanneling:Arcane Missiles] 13
/cast [nochanneling:Arcane Missiles] Arcane Blast

You should also do this to your scorch and/or fireblast spells in order to spam them, as casting AM and scorch/fireblast only gives you .5 seconds to again cast arcane blast before you lose the "buff/debuff"